﻿;########################################################;
;#                                                      #;
;#              monitor system definitions              #;
;#                                                      #;
;########################################################;


;       miscellaneous definitions:


jmp     equ     0c3h            ; jp instruction
rst7    equ     38h             ; rst 7 (location for trap)
ram     equ     rst7+3          ; start of available ram


;       constants


false   equ     0               ; isn't so
true    equ     not false       ; it is so
cr      equ     0dh             ; ascii carriage return
lf      equ     0ah             ; ascii line feed
bell    equ     7               ; ding
ctlc    equ     3               ; console abort character
ctls    equ     13h             ; console display freeze character
rbrace  equ     7dh             ; right brace character




;       zs floppy disk controller port definitions:


zfdcmd  equ     90h             ; command port
zfdsts  equ     zfdcmd          ; status port
zfdtrk  equ     zfdcmd+1        ; track register (in/out)
zfdsec  equ     zfdtrk+1        ; sector register (in/out)
zfddat  equ     zfdsec+1        ; data register (in/out)
zxsts   equ     zfddat+1        ; external status port (in)
zxctl   equ     zxsts           ; external control port (out)


;       1771/1793  floppy disk controller command definitions:


frcint  equ     0d0h            ; force interrupt cmd (set type 1 sts)
rate    equ     10b             ; steprate = 10 msec for shugart 800 drives
restor  equ     00h or rate     ; restore drv to trk 0 cmd
seek    equ     10h or rate     ; seek cmd
rdcmd   equ     88h             ; read single ibm record cmd
wrtcmd  equ     0a8h            ; write single ibm record (with data mark) cmd


;       1771/1793 floppy controller bit and mask definitions:


ebit    equ     2               ; e flag bit position
wrtbit  equ     5               ; bit position used to distinguish write cmd
hdlod   equ     5               ; head load status bit position in fdxsts
recnfd  equ     4               ; record not found status bit position
waiton  equ     80h             ; mask to enable wait synchronization logic
verfy   equ     04h             ; fd1771 verify mask for type i cmds
lodhd   equ     08h             ; fd1771 head load flag mask for type i cmds
rdmsk   equ     10011100b       ; read status error mask
wrtmsk  equ     11111100b       ; write status error mask
maxi    equ     10h             ; selects 8 " drive (zs)
mtrgo   equ     20h             ; turn drive motor on (zs)






;       macro definitions:


putcon  macro   #ch
        call    prnt
        defb    #ch or 80h
        endm


        form
;########################################################;
;#                                                      #;
;#               monitor entry point                    #;
;#                                                      #;
;########################################################;


        org     0f000h


begin:  ld      a,1
        out     (40h),a         ; select memory bank 0
        ld      sp,ahead-4      ; set up a fake stack
        jp      memsiz+1        ; get memory size
        defw    ahead
ahead:  ld      sp,hl           ; set true stack
        ex      de,hl
        ld      bc,endx-exit
        ld      hl,exit
        ldir                    ; move to ram
        ex      de,hl
        ld      bc,-5fh         ; set up a user's stack value
        add     hl,bc
        push    hl              ; pre-load stack value
        ld      hl,0            ; initialize other registers
        ld      b,10            ;   (16 of them)
stkit:  push    hl              ;     to zero
        djnz    stkit
        ld      hl,initbl       ; hl := ^i/o initialization tables
puttbl: ld      a,(hl)          ; a := length
        or      a
        jr      z,bootsw        ; done if length=0
        ld      b,a
        inc     hl
        ld      c,(hl)          ; c := port adr, b := length
        inc     hl
        otir                    ; output table data
        jr      puttbl
        ;
bootsw: in      a,95h           ; read boot sw on FDC
        and     a,40h           ; if on boot disk
        jp      z,bootin        ; if off goto monitor
sayhi:  in      a,(crtdat)      ; clear junk from console
        call    prnt            ; say ZOBEX 2d
        defm    cr,lf,'ZOBEX2'




start:  ; main processing loop for monitor
        ;
        ld      de,start
        push    de              ; set up a return to start
        call    prnt
        defm    cr,lf,'*'
star0:  call    ti              ; get a console char
        ld      hl,ctblnd
        ld      bc,ctblsz
        cpdr                    ; search cmd char table
        ld      hl,gotbl
        add     hl,bc
        add     hl,bc
        ld      e,(hl)
        inc     hl
        ld      d,(hl)
        ex      de,hl           ; HL := ^processing routine
        ld      c,2             ; set c up for 2 parms
        jp      (hl)            ; go execute cmd


        form
;########################################################;
;#                                                      #;
;#                 system tables                        #;
;#                                                      #;
;########################################################;


ctbl:   ; table of command characters
        ;
        defb    -1              ; token illegal
        defb    'B'             ; B - boot disk system
        defb    'D'             ; D - display memory in hex
        defb    'G'             ; G - goto [addr]<,> breakpoints (2)
        defb    'M'             ; M - move blocks of memory
        defb    'I'             ; I - input from port
        defb    'O'             ; O - output to port
        defb    'S'             ; S - substitute &/or examine memory
        defb    'X'             ; X - examine and modify cpu regs
ctblnd  equ     $-1             ; end of this table
ctblsz  equ     $-ctbl          ; size of this table




gotbl:  ; dispatch table for monitor commands
        ;
        defw    error           ; bad cmd
        defw    boot            ; B - boot disk system
        defw    disp            ; D - display memory in hex and ascii
        defw    goto            ; G - goto [addr]<,> breakpoints (2)
        defw    move            ; M - move blocks of memory
        defw    input           ; I - input from port
        defw    output          ; O - output to port
        defw    subs            ; S - substitute &/or examine memory
        defw    xam             ; X - examine and modify cpu regs




exit:   ; this is a short program, executed upon a "go"
        ; command.  it is placed in the work area when
        ; the monitor is initialized, as it requires ram
        ; for proper operation
        ;
        pop     hl
        ld      sp,hl
        nop                     ; reserved for enable interrupts
lstor   equ     $+1
        ld      hl,0
        jp      0




;   storage area for trap data


        defw    0
        defb    0
        defw    0
        defb    0
endx    equ     $




; displacements of register storage from normal stack location


aloc    equ     15h
bloc    equ     13h
cloc    equ     12h
dloc    equ     11h
eloc    equ     10h
floc    equ     14h
sloc    equ     17h
lloc    equ     sloc + lstor - exit + 1
hloc    equ     lloc + 1
ploc    equ     lloc + 4
tloc    equ     ploc + 1
tlocx   equ     tloc - 10h
llocx   equ     lloc - 10h
aploc   equ     09h
bploc   equ     0bh
cploc   equ     0ah
dploc   equ     0dh
eploc   equ     0ch
fploc   equ     08h
hploc   equ     0fh
lploc   equ     0eh
xloc    equ     07h
yloc    equ     05h
rloc    equ     02h
iloc    equ     03h




; these are the tables used to determine a valid
; register identifier and its displacement from
; the stack pointer
;
; position one = register name with bit 7 indicating
;                end of table
; position two = bias from current stack level or'ed
;                with a two-bit flag
;
;                00xxxxxx = byte
;                10xxxxxx = word
;                11xxxxxx = special for "m" register




actbl:  ; normal 8080 regs + interrupt reg "i"
        ;
        defb    'A',    aloc or 0
        defb    'B',    bloc or 0
        defb    'C',    cloc or 0
        defb    'D',    dloc or 0
        defb    'E',    eloc or 0
        defb    'F',    floc or 0
        defb    'H',    hloc or 0
        defb    'L',    lloc or 0
        defb    'M',    hloc or 0c0h
        defb    'P',    ploc or 080h
        defb    'S',    sloc or 080h
        defb    'I',    iloc or 0
        defb    80h


prmtb:  ; additional Z80 registers
        ;
        defb    'A',    aploc or 0
        defb    'B',    bploc or 0
        defb    'C',    cploc or 0
        defb    'D',    dploc or 0
        defb    'E',    eploc or 0
        defb    'F',    fploc or 0
        defb    'H',    hploc or 0
        defb    'L',    lploc or 0
        defb    'M',    hploc or 0c0h
        defb    'X',    xloc  or 080h
        defb    'Y',    yloc  or 080h
        defb    'R',    rloc  or 0
        defb    80h


        form
;########################################################;
;#                                                      #;
;#              breakpoint routine                      #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this is the breakpoint "trap" handling routine.     #;
;#  all user registers are saved for display purposes,  #;
;#  and the contents are restored when executing a "go" #;
;#  (g) command.                                        #;
;#                                                      #;
;########################################################;


trap:   push    hl              ; push all registers
        push    de
        push    bc
        push    af
        call    memsiz          ; get monitor's stack value
        ex      de,hl
        ld      hl,10           ; go up 10 bytes in stack
        add     hl,sp
        ld      b,4             ; pick off reg
        ex      de,hl
..r0:   dec     hl
        ld      (hl),d          ; save in work area
        dec     hl
        ld      (hl),e
        pop     de
        djnz    ..r0
        pop     bc
        dec     bc              ; adjust pc value
        ld      sp,hl           ; set monitor stack
        ld      hl,tlocx
        add     hl,sp
        ld      a,(hl)
        sub     c               ; look for a trap/match
        inc     hl
        jr      nz,..r1
        ld      a,(hl)
        sub     b
        jr      z,..r3          ; no trap here
..r1:   inc     hl
        inc     hl
        ld      a,(hl)
        sub     c               ; test for 2nd trap
        jr      nz,..r2
        inc     hl
        ld      a,(hl)
        sub     b
        jr      z,..r3
..r2:   inc     bc              ; no traps set - readjust pc
..r3:   ld      hl,llocx
        add     hl,sp
        ld      (hl),e          ; store user h/l
        inc     hl
        ld      (hl),d
        inc     hl
        inc     hl
        ld      (hl),c          ; store user pc
        inc     hl
        ld      (hl),b
        push    bc
        putcon  '@'             ; display break adr
        pop     hl
        call    ladr
        ld      hl,tlocx
        add     hl,sp
        ld      bc,200h
..r4:   ld      e,(hl)          ; replace bytes taken for trap
        ld      (hl),c          ; zero out storage area
        inc     hl
        ld      d,(hl)
        ld      (hl),c
        inc     hl
        ld      a,e
        or      d               ; do nothing if zero
        jr      z,..r5
        ld      a,(hl)
        ld      (de),a          ; store byte
..r5:   inc     hl              ; same thing
        djnz    ..r4            ;   for other breakpoint
        ex      af,af'          ; get alternate set of regs
        exx
        push    hl              ;   and store in work space
        push    de
        push    bc
        push    af
        push    ix
        push    iy
        ld      a,i             ; get interrupt vector byte
        ld      b,a
        ld      a,r             ; get refresh byte
        ld      c,a
        push    bc              ; save
        jp      start           ; back to start


        form
;########################################################;
;#                                                      #;
;#              B: boot disk system                     #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this routine allows the user to boot a disk system  #;
;#  using the zobex disk controller.  the routine       #;
;#  loads sector one, track zero into memory at loca-   #;
;#  tion 0000h and, if successful, branches to location #;
;#  0000h to execute the program.                       #;
;#                                                      #;
;#  syntax:                                             #;
;#      B[cr]                                           #;
;#                                                      #;
;########################################################;


boot:   call    pchk            ; get [cr]
        call    crlf
bootin: nop                     ;
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        call    bsychk          ; wait for controller ready
        ld      a,mtrgo or maxi or 1
        out     (zxctl),a       ; select drive 0
        ld      a,restor or lodhd or verfy
        out     (zfdcmd),a      ; restore to trk 0
        call    bsychk          ; wait 'til done
        ld      bc,128<<8 or zfddat
        ld      a,waiton or mtrgo or maxi or 1
        out     (zxctl),a       ; enable wait logic
        ld      a,1
        out     (zfdsec),a      ; sector := 1
        ld      hl,0080h        ; boot load adr
        ld      a,rdcmd
        out     (zfdcmd),a      ; issue read cmd
..b0:   in      a,(zxsts)
        ini
        jr      nz,..b0
        in      a,(zxsts)
        in      a,(zfdsts)
        or      a
        jp      z,0080h         ; boot ok
        jp      bootin          ; error, try again


bsychk: ;  wait until controller not busy
        ;
        ex      (sp),hl         ; delay for 1771
        ex      (sp),hl
        in      a,(zfdsts)
        rrca
        jr      c,bsychk        ; busy
        in      a,(zfdsts)      ; clear irq
        ret


        form
;########################################################;
;#                                                      #;
;#              D: display memory in hex                #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this routine displays the contents of memory in hex #;
;#  with the starting location on each line (within the #;
;#  specified range).  16 bytes per line max.           #;
;#                                                      #;
;#  syntax:                                             #;
;#      D<start address>,<end address>                  #;
;#                                                      #;
;########################################################;


disp:   call    expr            ; get display range
        pop     de
        pop     hl
..d0:   call    crlf
        call    hlsp            ; print adr, space
..d1:   ld      a,(hl)
        call    lbyte           ; print hex contents
        call    blk             ; space over
        call    hilox           ; check for done
        ld      a,l             ; see if time for crlf
        and     0fh
        jr      nz,..d1         ; continue with present line
        jr      ..d0            ; start a new line


        form
;########################################################;
;#                                                      #;
;#       G: goto <adr>, optionally set breakpoints      #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this command allows execution of another program    #;
;#  while retaining some monitor control by setting     #;
;#  breakpoints.  to simply execute, type 'G<adr>[cr]'. #;
;#  to set a breakpoint trap, add the address(es) to    #;
;#  the command; ie: G<adr>,<bkpt>[cr].  two breakpoints#;
;#  are allowed, enough to satisfy most requirements.   #;
;#  once a breakpoint has been reached, the registers   #;
;#  may be examined or modified.  the program can then  #;
;#  be continued by typing only a 'G[cr]' or another    #;
;#  breakpoint could be implemented at that time by     #;
;#  typing 'G,<bkpt>[cr]'.                              #;
;#                                                      #;
;#  * note: this is software controlled, and the break- #;
;#  point must occur on an instruction byte.            #;
;#                                                      #;
;########################################################;


goto:   call    pchk            ; get a possible adr
        jr      c,..g3          ; cr entered
        jr      z,..g0          ; delimiter entered
        call    exf             ; get one expression
        pop     de
        ld      hl,ploc         ; place adr in 'p' location
        add     hl,sp
        ld      (hl),d          ; high byte
        dec     hl
        ld      (hl),e          ; low byte
        ld      a,b
        cp      cr              ; see if last char was cr
        jr      z,..g3          ; yes, leave
..g0:   ld      d,2             ; two breakpoints max
        ld      hl,tloc         ; point to trap storage
        add     hl,sp
..g1:   push    hl              ; save storage pointer
        call    expr1           ; get a trap adr
        ld      e,b             ; save delimiter
        pop     bc              ; trap adr
        pop     hl              ; storage
        ld      a,b             ; look at trap adr
        or      c
        jr      z,..g2          ; don't set a trap at 0
        ld      (hl),c          ; save bkpt adr
        inc     hl
        ld      (hl),b
        inc     hl
        ld      a,(bc)          ; pick up instruction byte
        ld      (hl),a          ; save that too
        inc     hl
        ld      a,0ffh          ; rst 7
        ld      (bc),a          ; software interrupt
..g2:   ld      a,e             ; look at delimiter
        cp      cr
        jr      z,..g2a
        dec     d               ; count bkpts
        jr      nz,..g1         ; get one more
..g2a:  ld      a,jmp           ; set up jmp instruction
        ld      (rst7),a        ;  at restart trap loc
        ld      hl,trap         ;   to monitor vector
        ld      (rst7+1),hl
..g3:   call    crlf
        pop     de              ; clear system return
        pop     bc              ; load all regs
        ld      a,b
        ld      i,a
        ld      a,c
        ld      r,a
        pop     iy
        pop     ix
        pop     af
        pop     bc
        pop     de
        pop     hl
        ex      af,af'
        exx
        pop     de
        pop     bc
        pop     af
        ld      hl,2            ; find 'exit' routine
        add     hl,sp           ;  up in stack
        jp      (hl)            ; go someplace


        form
;########################################################;
;#                                                      #;
;#               M: move a block of memory              #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this command moves mass amounts of memory from <1>  #;
;#  to <2> to the address starting at <3>.  this rou-   #;
;#  tine should be used with some caution as it could   #;
;#  smash memory if carelessly used.                    #;
;#                                                      #;
;#      M<1>,<2>,<3>[cr]                                #;
;#                                                      #;
;########################################################;


move:   inc     c
        call    expr
        call    crlf
        pop     bc
        pop     de
        pop     hl
..m:    ld      a,(hl)          ; pick up
        ld      (bc),a          ; put down
        inc     bc              ; move up
        call    hilox           ; check if done
        jr      ..m




        form
;########################################################;
;#                                                      #;
;#                 I: input from a port                 #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this routine allows examination of any input port.  #;
;#                                                      #;
;#                                                      #;
;#  I<n>[cr]                                            #;
;#      display the port <n>                            #;
;#                                                      #;
;########################################################;


input:  call    expr1
        call    blk             ; space over
        pop     bc
        in      a,(c)
        jp      lbyte           ; print input data, return


        form
;########################################################;
;#                                                      #;
;#                 O: output to a port                  #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this routine allows the user to send any value to   #;
;#  any output port.                                    #;
;#                                                      #;
;#  O<n>,<v>[cr]                                        #;
;#      output to port <n>, the value <v>               #;
;#                                                      #;
;########################################################;


output: call    expr
        pop     de
        pop     bc
        out     (c),e
        ret


        form
;########################################################;
;#                                                      #;
;#               S: display/alter memory                #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this routine allows both inspection of and modifi-  #;
;#  cation of memory on a byte by byte basis.  it takes #;
;#  one address parameter, followed by a space.  the    #;
;#  data at that location will be displayed.  if it is  #;
;#  desired to change it, the value is then entered.  a #;
;#  following space will display the next byte.  a car- #;
;#  riage return[cr] will terminate the command.  the   #;
;#  system adds a crlf at locations ending with either  #;
;#  xxx0 or xxx8.  to aid in determining the present    #;
;#  address, it is printed after each crlf.             #;
;#                                                      #;
;########################################################;


subs:   call    expr1           ; get starting adr
        pop     hl
..s0:   ld      a,(hl)
        call    lbyte           ; display the byte
        call    copck           ; modify?
        ret     c               ; no, all done
        jr      z,..s1          ; don't modify
        push    hl              ; save pointer
        call    exf             ; get new value
        pop     de              ; value in e
        pop     hl
        ld      (hl),e          ; modify
        ld      a,b             ; test delimiter
        cp      cr
        ret     z               ; done
..s1:   inc     hl              ; point to next location
        ld      a,l             ; see if time for crlf
        and     7
        call    z,lfadr         ; time to crlf
        jr      ..s0


        form
;########################################################;
;#                                                      #;
;#          X: examine/modify cpu registers             #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  this routine allows displaying the user's cpu reg-  #;
;#  isters.  they may also be using the register name   #;
;#  after typing the "X".                               #;
;#      i.e.  XA 00-                                    #;
;#  the register may be skipped over, or modified, as   #;
;#  with the "s" command.                               #;
;#                                                      #;
;#  to display the normal system status, simply type    #;
;#  "X[cr]".  to display the additional z-80 registers, #;
;#  type "X'[cr]".  to examine a single "prime" regis-  #;
;#  ter, type the register identifier after the apos-   #;
;#  trophe.                                             #;
;#       i.e.  X'X 0000-                                #;
;#                                                      #;
;#  these register values are placed into the cpu upon  #;
;#  executing any "Go" command [G].                     #;
;#                                                      #;
;########################################################;


xam:    call    ti
        ld      hl,actbl
        cp      cr              ; full reg display
        jr      z,..x6
        cp      ''''            ; see if primes are wanted
        jr      nz,..x0
        ld      hl,prmtb
        call    ti
        cp      cr              ; full reg display
        jr      z,..x6
..x0:   cp      (hl)            ; test for reg name
        jr      z,..x1
        bit     7,(hl)          ; see if end of table
        jp      nz,error
        inc     hl
        inc     hl
        jr      ..x0


..x1:   call    blk
..x2:   inc     hl
        ld      a,(hl)
        ld      b,a             ; save for flags
        and     3fh             ; clear flags for bias
        ex      de,hl
        ld      l,a             ; displacement from stack
        ld      h,0
        add     hl,sp
        ex      de,hl
        inc     hl
        ld      a,(de)          ; pick up reg value
        call    lbyte           ; print it
        bit     7,b
        jr      z,..x3
        dec     de
        ld      a,(de)
        call    lbyte
..x3:   call    copck           ; modify?
        ret     c               ; cr entered, all done
        jr      z,..x5          ; skip to next reg
        push    hl
        push    bc
        call    exf             ; get new value
        pop     hl
        pop     af
        push    bc
        push    af
        ld      a,l
        ld      (de),a
        pop     bc
        bit     7,b             ; see if 8 or 16 bit reg
        jr      z,..x4          ; 8 bit
        inc     de
        ld      a,h             ; high byte of 16 bit reg
        ld      (de),a
..x4:   pop     bc
        pop     hl
        ld      a,b             ; test delimiter
        cp      cr
        ret     z
..x5:   bit     7,(hl)          ; see if end of table
        ret     nz              ; yes - return
        jr      ..x2


..x6:   call    crlf
..x7:   call    blk
        ld      a,(hl)
        inc     hl
        or      a
        ret     m
        ld      c,a
        call    co
        putcon  '='
        ld      a,(hl)
        ld      b,a             ; save flags
        and     3fh             ; clean up for offset
        inc     hl
        ex      de,hl
        ld      l,a
        ld      h,0
        add     hl,sp
        ex      de,hl
        bit     6,b             ; test for special "m"
        jr      nz,..x9         ; print out actual "m"
        ld      a,(de)
        call    lbyte           ; print reg value
        bit     7,b             ; single or double?
        jr      z,..x7          ; single
        dec     de
        ld      a,(de)
..x8:   call    lbyte
        jr      ..x7


..x9:   push    hl              ; save
        ld      a,(de)          ; get reg pointer
        ld      h,a             ; high byte
        dec     de
        ld      a,(de)
        ld      l,a             ; low byte
        ld      a,(hl)          ; get value
        pop     hl              ; restore
        jr      ..x8            ; print value and continue




        form
;########################################################;
;#                                                      #;
;#                      subroutines                     #;
;#                                                      #;
;########################################################;


prnt:   ; print string following call 'til char with bit 7 set
        ;
        call    cchk            ; check for abort or freeze
        ex      (sp),hl         ; h/l := adr of msg
..p0:   ld      c,(hl)          ; c = print data
        res     7,c             ; make sure parity reset
        call    co              ; print the char
        bit     7,(hl)          ; z flag = 0 if done
        inc     hl              ; advance to next char
        jr      z,..p0          ; loop
        ex      (sp),hl         ; restore return adr
        ret




cchk:   ; chk for console abort or display halt
        ;
        in      a,(crtsts)
        and     rda
        ret     z               ; exit if no kbd input
        call    ci
        cp      ctlc            ; abort if ^c
        jr      z,abort
        cp      ctls            ; freeze display if ^s
        ret     nz
        call    ci
        cp      ctlc
        jr      z,abort         ; abort if ^c
        ret




error:  ; system error routine
        ; this will restore the system after a system error has
        ; been detected. the i/o configuration is not affected
        ;
        putcon  '?'             ; indicate error
abort:  call    memsiz
        ld      de,-22          ; stack pointer offset
        add     hl,de
        ld      sp,hl           ; reset stack
        jp      start           ; back to work




lfadr:  ; cr,lf, print adr, space
        ;
        call    crlf


hlsp:   ; print adr, space
        ;
        call    ladr


blk:    ; print a space
        ;
        putcon  ' '
        ret




conv:   ; hex/ascii conversion
        ;
        and     0fh             ; isolate lower nibble
        add     90h
        daa
        adc     40h
        daa
        ld      c,a
        ret




crlf:   ; type carriage return/linefeed at console --
        ;
        call    prnt
        defm    cr,lf
        ret




expr1:  ; get 1 parameter
        ;
        ld      c,1




expr:   ; this is the main "parameter-getting" routine.
        ; this routine will abort on a non-hex character.
        ; it takes the four most recently typed valid hex
        ; characters, and places them up on the stack
        ; (as one 16 bit value, contained in two 8-bit bytes).
        ; if a carriage return is entered, it will place the
        ; value of "0000" in the stack.
        ;
        ld      hl,0            ; initialize h/l to zero
ex0:    call    ti              ; get something from console
ex1:    ld      b,a             ; save it
        call    nibble          ; convert ascii to hex
        jr      c,..ex2         ; illegal char detected
        add     hl,hl           ; multiply by 16
        add     hl,hl
        add     hl,hl
        add     hl,hl
        or      l               ; or in the single nibble
        ld      l,a
        jr      ex0             ; get some more


..ex2:  ex      (sp),hl         ; save up in stack
        push    hl              ; replace the return
        ld      a,b             ; test the delimiter
        call    qchk
        jr      nc,..ex3        ; cr entered
        dec     c               ; should go to zero
        ret     z               ; it does
..ex3:  jp      nz,error        ; something wrong
        dec     c               ; do this again?
        jr      nz,expr         ; yes
        ret                     ; else return


exf:    ld      c,1
        ld      hl,0
        jr      ex1




hilox:  ; range test with exit
        ;
        ; Exit:   carry set indicates range exceeded
        ;
        call    hilo
        ret     nc              ; ok
        pop     de              ; return one level back
        ret




hilo:   ; range test
        ;
        ; Exit:   carry set indicates range exceeded
        ;
        inc     hl
        ld      a,h             ; test for wrap-around
        or      l
        scf                     ; carry set = stop
        ret     z               ; wrapped around
        ld      a,e             ; now, test h/l vs. d/e
        sub     l
        ld      a,d
        sbc     h
        ret                     ; if carry set, stop




ladr:   ; print address
        ;
        ld      a,h
        call    lbyte
        ld      a,l




lbyte:  ; print the hex byte in A as 2 ascii characters on the console
        ;
        push    af
        rrca
        rrca
        rrca
        rrca
        call    ..2
        pop     af
..2:    call    conv
        jp      co






memsiz: ; this is a routine used to calculate the top
        ; of memory starting from the bottom of memory,
        ; and searching upward until first r/w memory is
        ; found, and then continuing until the end of the r/w
        ; memory.  this allows rom at zero, and ensures a
        ; continuous memory block has been found. it is
        ; used by the error routine to reset the stack pointer
        ; as well
        ;
        push    bc
        ld      hl,-1           ; ram search starting point
..m1:   inc     h               ; find end of r/w memory
        ld      a,(hl)
        cpl
        ld      (hl),a
        cp      (hl)
        cpl
        ld      (hl),a
        jr      nz,..m2
        ld      a,h             ; test for monitor border
        cp      begin/256
        jr      nz,..m1         ; not there yet
..m2:   dec     h               ; back up, subtract workspace
        ld      bc,exit-endx
        add     hl,bc
        pop     bc              ; restore
        ret                     ; value in h/l




nibble: ; convert ascii characters into hex digits. if
        ; invalid character detected, return with cy = 1
        ;
        sub     '0'             ; qualify and convert
        ret     c               ; < 0
        cp      'G'-'0'         ; > f?
        ccf                     ; flip carry
        ret     c
        cp      10              ; number?
        ccf                     ; flip again
        ret     nc              ; return clear
        sub     'A'-'9'-1       ; adjust
        cp      0ah             ; filter ':' thru '@'
        ret




copck:  putcon  '-'


pchk:   call    ti


qchk:   ; test for delimiters, return Z = 1 if delimiter
        ; CY = 1 if CR
        ;
        cp      ' '
        ret     z
        cp      ','
        ret     z
        cp      cr              ; return with carry set if cr
        scf
        ret     z
        ccf                     ; else non-zero, no carry
        ret




ti:     ; this is the internal keyboard handling routine.
        ; it will not echo cr's.  it converts lower case
        ; to upper case for the look-up of commands.
        ; other characters are echoed as they are received
        ;
        call    ci
        cp      cr              ; ignore cr's
        ret     z
        push    bc
        ld      c,a
        call    co
        ld      a,c
        pop     bc
        cp      'a'             ; convert to upper case
        ret     c
        cp      'z'+1
        ret     nc
        sub     a,'a'-'A'
        ret


        form
;########################################################;
;#                                                      #;
;#                   i/o routines                       #;
;#                                                      #;
;########################################################;


ctc0    equ     04h             ; ctc channel 0
ctc1    equ     ctc0+1          ; ctc channel 1
ctc2    equ     ctc1+1          ; ctc channel 2
ctc3    equ     ctc2+1          ; ctc channel 3


crtdat  equ     00h             ; data port
crtsts  equ     crtdat+1        ; status port
crtctl  equ     crtsts          ; control port
rda     equ     01h             ; receiver data available mask
tbe     equ     04h             ; transmit buffer empty mask




co:     ; crt character output routine
        ; enter with char in reg c
        ;
        in      a,(crtsts)
        and     tbe
        jr      z,co            ; wait 'til prev char printed
        ld      a,c             ; get char
        out     (crtdat),a      ;  and print it
        ret




ci:     ; crt character input routine
        ; char returned in reg a with parity trimmed
        ;
        in      a,(crtsts)
        and     rda
        jr      z,ci            ; loop 'til char available
        in      a,(crtdat)      ; read char
        and     7fh             ; trim parity
        ret




initbl  equ     $


        defb    size2,ctc0              ; ctc channel 0 (baudrate = 9600)
j       defv    $
        defb    01000101b,04h
size2   equ     $-j


        defb    size1,crtctl            ; sio # 1 channel A
j       defv    $
        defb    00011000b
        defb    00010100b,10000100b
        defb    00000011b,11000001b
        defb    00000101b,11101010b
size1   equ     $-j


        defb    0


        end     begin